Lors de l’importation de données d’un fichier Excel, il est fréquent d’importer au passage des caractères spéciaux non visible au premier coup d’œil. Par exemple, on peut trouver des blancs représentés en valeur hexadécimale par le code 20. Certains de ses caractères ressemblent à des blancs mais n’en sont pas. Ils ne disparaîtront donc pas avec une fonction COMPRESS sans troisième paramètre. La valeur hexadécimale de ces caractères est par contre une valeur lisible.

Voici comment afficher votre texte en valeur hexadécimale et ce dans la log ?

1. Illustration du problème

Dans cet exemple, une variable WEBISTE de longueur 25 est présente dans la table HEXFMT. Cette variable contient une observation www.sasreference.fr entourée d’un blanc avant et d’un blanc après. Cette valeur est créée ici au moyen de la fonction CAT.

Pour voir la différence entre la valeur de WEBSITE avec et sans un simple COMPRESS, une seconde variable EQUAL indique la valeur YES si les deux résultats sont identiques, NO sinon.

data hexfmt;
length website $25 equal $3;
website=cat(‘20′x,‘www.sasreference.fr’,‘20′x);
if website=compress(website) then equal=‘Yes’;
else equal=‘No’;
run;

proc print data=hexfmt;
run;

2. Voir les caractères hexadécimaux avec le format HEX

Ici, je vous propose de voir la valeur de la variable WEBSITE au moyen de l’instruction PUT. Il est possible de voir la valeur formatée plutôt que la valeur brute en faisant suivre la variable d’un format. Le format ici sera HEXw. où w est un nombre idéalement de la longueur de la variable fois deux. En effet, les caractères hexadécimaux sont toujours de longueur deux. Si votre texte est de longueur 25, il faudra 50 caractères pour l’afficher en valeur hexadécimale.

data hexfmt;
length website $25;
website=cat(‘20′x,‘www.sasreference.fr’,‘20′x);
put website= hex50.;
run;

proc print data=hexfmt;
run;

Dans le résultat qui suit, on voit donc le premier caractère de l’observation de WEBSITE a pour code 20. Le second caractère est la lettre W représentée par le code 77, et ainsi de suite.

Lecture complémentaire

• Remplacer un mot par un autre : la fonction TRANWRD

Vous avez des nombres et du texte sauvegardés dans une variable caractère dans une table sAS et vous voulez sauvegarder les données numériques dans une variable numérique sans avoir dans la log une indication d’erreur (_ERROR_=1) pour les valeurs non compatibles. Comment adapter la fonction INPUT ?

1. Les données pour l’exemple

Pour l’exemple,  nous avons un dataset appelé CHAR avec une variable caractère, X_CHAR et 5 observations.

data char;
length x_char $10;
input x_char $ 1-10;
datalines;
-1.3
- 5
5.3.2
18.9
AB
;
run;

2. Le résultat attendu

Nous voudrons que la première et la quatrième observation soient converties en nombre. En effet,les trois autres valeurs ne sont pas convertibles.

• La seconde observations est non valide à cause de l’espace séparant le signe moins et le nombre 5.
• La troisième observation a plus d’un point
• La dernière observation est un texte.

3. La version traditionnelle

La fonction INPUT permet de passer d’une variable caractère à une variable numérique. Elle est composée de deux paramètres : le nom de la variable caractère à convertir (ou une valeur entre guillemets) et l’informat qui permet d’interpréter les valeurs de la variable.

data char_num;
set char;
x_num=input(x_char,20.6);
run;

Malheureusement, SAS n’est pas totalement satisfait de cette action pour les valeurs ne répondant pas aux critères de l’informat.

4. Une log propre grâce au point d’interrogation

Le double point d’interrogation précédent le nom de l’informat empêchera la log d’avoir la note. Bien sûr, cela n’a d’intérêt que si vous avez de bonnes raisons d’ignorer ce message d’erreur. Le cas contraire, vérifiez vos données.

data char_num;
set char;
x_num=input(x_char,??20.6);
run;

Note : si la fonction INPUT est utilisée dans l’option de data set WHERE, un WARNING apparaît.

data char_num ;
set char (where=(input(x_char,20.6)=18.9));
run;

Ce warning ne peut être enlevé avec le point d’interrogation. Il crée même une erreur dans la log.

Lecture complémentaire

• Créer une variable caractère en numérique et inversement
• Créer une date de trois manières

Dans cet article, je vous propose d’ajouter des liens hypertextes dans vos fichiers .PDF créés avec la syntaxe de l’ODS PDF. Pour illustrer ce sujet, nous créerons une table des matières (table of contents ou TOC) rustique avec ODS PDF TEXT=’ ‘; où il suffira de cliquer sur la section qui vous intéresse pour l’atteindre.

1. Le principe de base

Pour ajouter des liens hypertextes, il faut deux informations :

• la location du point d’encrage/de destination (anchor)
• le lien vers ce point d’encrage

ods escapechar=‘^’;

ods listing close;
ods pdf file=‘C:/sasref/hyperlink_toc.pdf’;

ods pdf text=‘Table of Contents’;
ods pdf text=”;
ods pdf text=‘^S={url=’#hommes’}1. Hommes’;
ods pdf text=‘^S={url=’#femmes’}2. Femmes’;

ods pdf anchor=‘hommes’;
ods pdf text=‘1. Hommes’;
proc print data=sashelp.class(where=(sex=‘M’));
run;

ods pdf anchor=‘femmes’;
ods pdf text=‘2. Femmes’;
proc print data=sashelp.class(where=(sex=‘F’));
run;

ods pdf close;
ods listing;

Le point d’encrage : Le point d’encrage est donné par l’instruction ods pdf anchor=‘…’;. Entre guillemets est donné un nom de votre choix qui servira à l’identifier.

Le lien hypertexte : Le lien vers ce point d’encrage est donné par le mot URL à préciser sous forme de style donné au texte sur lequel cliquer.

ods pdf text=‘^S={url=’#…’}Je clique ici’;

Définition d’un style : Le style est défini avant le texte par S={…}. Pour indiquer à SAS qu’il faille interpréter ce texte comme un style et non un texte brut, un caractère doit précédé le tout. J’ai choisi le symbole du chapeau défini auparavant avec l’instruction ods escapechar=‘^’;

2. Personnaliser le style

Supprimer l’affichage du bookmark : Dans la version enrichie qui suit, j’ai choisi l’option NOTOC pour éviter l’affichage du bookmark sur la gauche de l’écran propre aux fichier PDF.

Les sauts de pages à la demande: J’ai aussi choisi d’enlever par défaut tous les sauts de pages ods pdf startpage=never; puis d’ajouter une fois un saut de page entre la table des matières et les tableaux avec ods pdf startpage=now;

Les en-têtes en moins : Le titre par défaut, la date et le numéro des pages sont enlevés :

title;
options nodate nonumber;

Les liens hypertextes invisibles : Par défaut, le lien hypertexte est présenté par un cadre bleu autour du texte à cliquer. Pour enlever ce cadre, travaillez le style avec ACTIVELINKCOLOR, VISITEDLINKCOLOR et LINKCOLOR.

ods pdf text=“^S={activelinkcolor=white
visitedlinkcolor=white
linkcolor=white
url=’…’}…”;

D’autres styles permettent ici d’affiner la présentation :

• VJUST : ajustement vertical du texte
• CELLHEIGHT : hauteur de la case contenant le texte
• CELLWIDTH : largeur de la case contenant le texte
• FONT_FACE : la police de style
• FONT_SIZE : la taille du texte
• INDENT : l’indentation du texte
• FONT_WEIGHT : mise en gras du texte

J’ai choisi de sauvegarder ces informations dans des macros variables pour pouvoir centraliser l’information en début de programme.

3. Le résultat

Deux pages sont donc créées. La première contient la table des matières. Vous pouvez cliquer sur le texte 1. Hommes ou 2. Femmes pour rejoindre le tableau qui vous intéresse.

Annexe : l’intégralité du code

%let titl=vjust=middle
cellheight=30pt
cellwidth=17cm
font_face=arial
activelinkcolor=white
visitedlinkcolor=white
linkcolor=white;
%let titl1=&titl indent=5cm font_size=16pt font_weight=bold;
%let titl2=&titl indent=6cm font_size=12pt;

title;
options nonumber nodate;
ods escapechar=’^';

ods listing close;
ods pdf file=‘C:/sasref/hyperlink_toc.pdf’ notoc startpage=never;

ods pdf text=“^S={&titl1.}Table of Contents”;
ods pdf text=”;
ods pdf text=“^S={&titl2. url=’#hommes’}1. Hommes”;
ods pdf text=“^S={&titl2. url=’#femmes’}2. Femmes”;

ods pdf startpage=now;

ods pdf anchor=‘hommes’;
ods pdf text=“^S={&titl2.}1. Hommes”;
proc print data=sashelp.class(where=(sex=‘M’));
run;

ods pdf anchor=‘femmes’;
ods pdf text=“^S={&titl2.}2. Femmes”;
proc print data=sashelp.class(where=(sex=‘F’));
run;

ods pdf close;
ods listing;

Dans l’article “Sauvegarder une macro au delà d’une session“, vous avez vu comment créer un catalogue permanent pour macro. Ici, je vous propose d’appeler une macro contenue dans un de ces catalogues.

1. Rappel : ajouter une entrée dans un catalogue pour macro

libname sasref ‘C:/sasref’;
options sasmstore=sasref mstored;

%macro perm_macro /store;
proc print data=sashelp.class;
run;
%mend perm_macro;

2. Appeler une macro compilée

Les options globales qui indique la position d’un catalogue pour macros sont MSTORED et SASMSTORE= où SASMSTORE est suivi du nom de la bibliothèque.

libname sasref ‘C:/sasref’;
options mstored sasmstore=sasref;
%perm_macro;

Lectures complémentaires

• Sauvegarder une macro au delà d’une session

Dans de précédents articles, je vous ai parlé de la possibilité de changer le style des cellules d’un tableau. Je vous invite ici à découvrir comment un format peut vous éviter de passer par un COMPUTE/ENDCOMP de PROC REPORT pour changer le style selon les valeurs prises par une variable donnée.

1. Créer les formats pour l’exemple

Pour mettre en gras (bold) ou non, il faut passer par le style FONT_WEIGHT. Dans notre exemple, ce style prendra la valeur BOLD quand la variable AGE aura des valeurs entre 14 et 16 ans et un LIGHT pour un style non gras. Vous avez aussi à disposition la valeur MEDIUM pour un ton légèrement plus prononcé.

Pour changer la couleur du texte, c’est le style FOREGROUND qu’il faut utiliser. Dans notre cas, le texte aura la couleur bleu si la variable AGE est comprise entre 14 et 16 ans inclus.

proc format;
value age_font 11-13=‘light’
14-16=‘bold’;
value age_color 14-16=‘blue’;
run;

2. Utiliser le format dans PROC REPORT

Pour changer le style d’une colonne en particulier, il suffit d’ajouter style(column)=[...] dans l’instruction DEFINE.

Ici au lieu de donner une couleur à toutes les valeurs avec FOREGROUND= suivi du nom de la couleur, on donne le format AGE_COLOR. qui prendra la valeur BLUE pour les AGE des 14-16 ans.

De manière similaire, l’épaisseur du trait est changée avec FONT_WEIGHT et le format AGE_FONT. défini auparavant.

ods listing close;
ods pdf file=‘C:/sasref/zebre.pdf’;
proc report data=sashelp.class nowd;
columns name age;
define name / display ;
define age / display style(column)=[font_weight=age_font. foreground=age_color.];
run;
ods pdf close;
ods listing;

3. Voir le résultat

Lectures complémentaires

• Alterner les couleurs de fond dans un tableau : une ligne sur deux (PROC REPORT et ODS)
• Changer la couleur d’une ligne ou d’une colonne grâce à PROC REPORT et ODS
• Un moyen simple de changer les couleurs en fonction des valeurs prises par des variables dans un fichier .xls
• Choisir ses couleurs sous SAS

Des questions ? Envoyez votre message sur le forum du blog.

Aujourd’hui, je voulais vous parler de la différence entre les instructions RUN et QUIT.  Toby Dunn a écrit une explication très bien faite sur le forum anglophone SAS-L. Voici une traduction possible.

1. L’instruction RUN

L’instruction RUN dit à SAS d’exécuter les instructions précédentes (c’est-à-dire l’étape data qui vient d’être compilée ou la procédure). C’est un délimiteur d’étape qui dit : “c’est la fin de l’étape ou de la procédure. Maintenant exécute le code.”.

Vous n’avez pas besoin d’utiliser l’instruction RUN, le début d’une autre étape data ou d’une procédure feront le boulot aussi. Cependant utiliser une instruction RUN nettoiera votre log.

2. L’instruction QUIT

L’instruction QUIT est aussi un délimiteur d’étape. Quelques procédures (par exemple PROC DATASETS, PROC CATALOG) permettent de soumettre plusieurs étapes à l’intérieur d’une procédure sans avoir à terminer la procédure. Dans ces cas là, vous ajoutez une instruction RUN pour terminer une étape dans cette procédure et une instruction QUIT pour terminer la procédure.

3. Le cas particulier de PROC SQL

SQL est un peu l’exception qui confirme la règle car cette procédure nécessite une instruction QUIT et toute instruction RUN sera ignorée. Ceci est dû au fait qu’elle exécute chaque instruction automatiquement. Il n’y a donc aucun besoin d’une exécution par groupe avec RUN mais un réel besoin d’un délimiteur de fin d’étape.

L’envoi de fichiers AS par email peut se faire au moyen de fichiers “compressés” appelés fichiers de transport (transport files). Ces fichiers ont une extension .xpt. Dans cet article, vous verrez deux choses :

• Comment créer un fichier .xpt
• Comment extraire les données d’un fichier .xpt

1. Créer un fichier .xpt avec la procédure CPORT

Dans l’exemple ci-dessous, la table CLASS de la bibliothèque SASHELP est ajoutée dans le fichier de transport SASHELP_CLASS.XPT.

filename tranfile ‘C:/sasref/transport_files/sashelp_class.xpt’;
proc cport lib=sashelp file=tranfile memtype=data;
select class;
run;

Quels fichiers envoyer ?

• LIB= : Pour ce faire, il faut préciser le nom de la bibliothèque contenant les fichiers à traiter avec LIB= : Si aucune bibliothèque n’est précisée, c’est la bibliothèque WORK qui est consultée.
• SELECT : les fichiers SAS à ajouter sont listés dans l’instruction SELECT. Si aucune instruction SELECT n’est fournie, tous les fichiers sont copiés.
• MEMTYPE= : L’option MEMTYPE restreint la sélection des fichiers aux tables SAS. Ainsi deux fichiers CLASS sont présents dans la bibliothèque SASHELP (une vue et une table) alors seule la table sera utilisée.

Où sauvegarder les données ? Le nom et la destination du fichier de transport sont définis dans une instruction FILENAME. Cette référence au fichier, nommée TRANFILE, est ensuite appelé par FILE=.

2. Extraire les données d’un fichier .xpt avec la procédure CIMPORT

Dans l’exemple qui suit, les données du fichier transport SASHELP_CLASS.XPT sont extraites et sauvegardées dans la bibliothèque EXTRACT.

libname extract ‘C:/sasref/extracted_files’;
filename sasref ‘C:/sasref/transport_files/sashelp_class.xpt’;
proc cimport lib=extract infile=sasref;
run;

Pour extraire les fichiers d’un fichier de transport, il y a l’option la procédure PROT CIMPORT.

Quelle destination ? L’option LIB= précise la bibliothèque de destination des fichiers contenus dans le fichier de transport.

Quelle source ? L’option INFILE= indique le nom et le chemin d’accès au fichier de transport.

Lectures complémentaires

Articles du blog

• Passer d’un fichier de l’ODS TAGSETS.EXCELXP à un data set SAS avec PROC IMPORT
• Les pièges d’Excel : une colonne sans nom (GETNAMES=YES)
• Les pièges d’Excel : cellules formatées

SAS Online Doc :

• The CPORT Procedure
• The CPORT Procedure for Unix
• The CPORT Procedure for Windows
• The CPORT Procedure for z/OS

• The CIMPORT Procedure
• The CIMPORT Procedure for Unix
• The CIMPORT Procedure for Windows
• The CIMPORT Procedure for z/OS

Comment couper ses titres et ajouter des indentations dans un fichier PDF avec SAS ? La solution deux petits mots-clés -2n et m précédés d’un symbole défini par vous-même auparavant.

Notez que cette syntaxe fonctionne aussi pour les pieds-de-page.

Si le passage à la ligne fonction avec ODS RTF, l’indentation par contre n’est pas prise en compte.

1. Par défaut un titre est sur une seule ligne

Dans l’exemple qui suit, un titre est donné dans une instruction TITLE.

Ce titre est aligné à gauche (J=L entendez par là justify=left).

Pour faciliter la lecture du programme, le titre est écrit sur plusieurs lignes. Mais au final, tout le texte apparaît sans passage à la ligne.

ods listing close;
title j=l
‘SASHELP.CLASS:’
‘Première Variable: Nom’
‘Seconde Variable: Sex’
‘Troisième Variable: Age’;
ods pdf file=‘C:/sasref/indent_title.pdf’;
proc print data=sashelp.class noobs;
run;
ods pdf close;
ods listing;

2. Passer à la ligne avec ODS ESCAPECHAR et ^-2n

A présent, un passage à la ligne est créé avec le mot -2n.

Pour que SAS n’utilise par ce mot comme un texte devant apparaître dans le titre, ce mot est précédent d’un symbole de son choix (ici un chapeau) défini précédemment avec l’instruction ODS ESCAPECHAR.

ods escapechar=‘^’;
ods listing close;
title j=l
‘SASHELP.CLASS:’
‘^-2nPremière Variable: Nom’
‘^-2nSeconde Variable: Sex’
‘^-2nTroisième Variable: Age’;
ods pdf file=‘C:/sasref/indent_title.pdf’;
proc print data=sashelp.class noobs;
run;
ods pdf close;
ods listing;

3. Passer à la ligne et indenter le titre avec ODS ESCAPECHAR, ^-2n et ^m

A présent, l’encre ^m est ajoutée en4ème position dans la première ligne. Cela veut dire que tout le texte qui suit est indenté et débutera en position 4 sous la lettre H de SASHELP.CLASS.

ods escapechar=‘^’;
ods listing close;
title j=l
‘SAS^mHELP.CLASS:’
‘^-2nPremière Variable: Nom’
‘^-2nSeconde Variable: Sex’
‘^-2nTroisième Variable: Age’;
ods pdf file=‘C:/sasref/indent_title.pdf’;
proc print data=sashelp.class noobs;
run;
ods pdf close;
ods listing;

Lectures complémentaires

• PDF can be Pretty Darn Fancy (SUGI .pdf)
• 9 points pour personnaliser ses titres

N’avez-vous jamais eu le sentiment de devoir taper toujours un même code sous SAS avec ODS TAGSETX.EXCELXP ou encore de ne pas vous rappeler la syntaxe exacte pour un PROC IMPORT ?

Une solution est de créer un programme de référence et de faire du copier/coller. Une autre solution, propre à SAS Windows, est de sauvegarder chaque code sous une abréviation et d’utiliser au moment venu cette abréviation. Voici comment cela marche.

1. Créer une abbréviation

Pour créer un abréviation, choisissez Tools/Add Abbreviation... dans le menu.

Ici, je choisi de créer l’abréviation report_xls. J’ajoute par copier/coller le code propre au tagsets.excelxp dans le second champs.

2. Comment utiliser l’abréviation

Dans l’éditeur SAS, saisissez le nom de l’abréviation. En tapant sur entrer le mot est remplacer le texte sous-jacent.

3. Modifier une abréviation existante

Si vous créer une nouvelle abréviation et lui donnez le même nom qu’une déjà existante, SAS vous demandera si vous souhaitez remplacer celle existante ou non.

4. Visualiser les abréviations existantes et les supprimer

Pour voir les abréviations existantes, aller dans le menu et choisissez Tools/Keyboard Macros/Macros…

Il ne vous reste plus qu’à sélectionner l’abréviation à supprimer et de cliquer sur Delete.

Source : http://www.pharmasug.org/content/view/132/153/

La liste des polices de caractères pour construire des graphiques sous SAS a longtemps été très limitée. Depuis SAS a racheté de nouvelles polices se rapprochant des classiques comme Arial. Mais pour l’instant, voici les styles disponibles depuis de nombreuses années. La mise en image de ces polices devrait vous aider à faire un choix plus rapide.

1. Trois fonts avec ses variantes

Ajoutez aux mots CENT, SWISS, ZAPF les lettres

• l pour une version comprimée,
• x pour une version étendue/allongée,
• b (bold) pour mettre en gras,
• i (italic) pour mettre en italic,
• e (empty) pour avoir un un font blanc.

2. Quelques autres styles

A ces trois premières polices s’ajoutent:

• BRUSH,
• SIMPLEX/DUPLEX/COMPLEX/TRIPLEX,
• SCRIPT/CSCRIPT
• GERMAN/GITALIC/OLDENG
• ITALIC/TITALIC

Ici, je vous propose d’illustrer l’usage de l’option notoc_data dans l’instruction ODS RTF sous SAS. Celle-ci empêche la création des points de références nécessaires à la création d’une table des matières. En effet, ces points affectent l’affichage des tableaux sur l’écran. Comment dissimuler/supprimer ces points pour améliorer la lisibilité de vos documents RTF ?

1. L’affichage par défaut

Pour pouvoir ajouter une table des matières (Table of Contents, TOC) dans un document Word, des marques aux différents points de références appelés ancres (anchers) au fil du document doivent exister. Ces points n’apparaissent pas à l’impression.

Lors de la création d’un fichier .rtf par SAS, ces points de référence sont automatiquement créés. Et cela peut donner une distorsion des tableaux comme dans l’exemple ci-dessous.

ods listing close;
ods rtf file=‘C:/sasref/toc.rtf’;
proc print data=sashelp.class;
run;
ods rtf close;
ods listing;

Avec un PROC PRINT, le point de référence ressemble à ceci :

{tc “print” \f C \l 1}{tc “Data Set SASHELP.CLASS ” \f C \l 2}

Avec un PROC REPORT, le point de référence se présente est :

{tc “Report ” \f \C \l 1}{tc “Detailed and/or summarized report ” \f C \l2}

Pour palier à ce problèmes deux solutions sont envisageable.

1. Désactiver l’affichage des symboles comme le passage à la ligne
2. Ne pas créer de points de références pour la table des matières

2. Désactiver l’affichage des symboles

Il suffira de cliquer sur le bouton servant à l’affichage des symboles comme le passage à la ligne, la tabulation,… pour ne plus voir les points de références utilisés si une table des matières est créée.

3. Ne pas créer de points de référence pour la table des matières avec l’option notoc_data

Il vous suffira d’ajouter l’option notoc_data dans l’instruction ODS RTF de départ pour ôter les points de référence servant pour la création d’une table des matières.

ods listing close;
ods rtf file=‘C:/sasref/toc.rtf’ notoc_data;
proc print data=sashelp.class;
run;
ods rtf close;
ods listing;

La syntaxe de l’ODS PDF sous SAS sert à la création d’un fichier au format pdf. Ici, vous verrez comment organiser les différents blocs de textes au moyen de ODS LAYOUT et ODS REGION. Cela sera aussi l’occasion de faire un rappel sur PROC TEMPLATE pour changer les marges d’un document et de se servir de l’instruction ODS PDF TEXT=.

1.Changer les valeurs par défaut

Par défaut, les sorties sous SAS affichent la date, un titre et chaque page est numérotée. Pour enlever ces informations, l’instruction TITLE et les options NODATE, NONUMBER sont utilisées.

* 1. Setting;
options nodate nonumber;
title;

Par défaut, les marges des feuilles A4 ne sont pas de zéro. Pour les changer, il faut utiliser un style différent à définir dans une procéduren PROC TEMPLATE. Ici, nous créons un style appelé REPORT_PDF qui est comme le style RTF de SAS à une exception prêt : les marges du document sont de zéro centimètre.

*2. Créer le template REPORT_PDF;
proc template;
define style styles.report_pdf;
parent=styles.rtf;
style body from Document /
bottommargin = 0cm
topmargin    = 0cm
rightmargin  = 0cm
leftmargin   = 0cm;
end;
run;

Note : vous pouvez aussi choisir de rendre non défini les marges au niveau du proc template dans un premier temps. Ensuite, vous pourrez définir la valeur dans une instruction globale OPTIONS.

proc template;
define style styles.report_pdf;
parent=styles.rtf;
style body from Document /
bottommargin = _undef_
topmargin    = _undef_
rightmargin  = _undef_
leftmargin   = _undef_;
end;
run;

options bottommargin=0cm topmargin=0cm rightmargin=0cm leftmargin=0cm;

Ici, j’ai choisi d’ajouter manuellement du texte au moyen de l’ODS PDF TEXT dans le fichier PDF pour illustrer l’usage d’ODS LAYOUT/ODS REGION. Au niveau de PROC TEMPLATE, il est possible de préciser la police de caractère et la taille. Ici je choisi une police Arial de taille 12pt.

proc template;
define style styles.report_pdf;
parent=styles.rtf;
style body from Document /
bottommargin = 0cm
topmargin    = 0cm
rightmargin  = 0cm
leftmargin    = 0cm;
style usertext from usertext /
font_size = 12pt
font_face = ‘Arial’;
end;
run;

2. Créer le fichier

a. ODS LISTING : Stopper l’envoi dans la fenêtre OUTPUT et réactiver cette destination à la fin

ods listing close;
ods listing;

b. ODS PDF :  Envoyer les résultats à venir dans un fichier PDF, appeler le style REPORT_PDF pour ne pas utiliser le style par défaut et stopper la destination en fin de programme.

ods pdf file=‘C:/sasref/ods_layout.pdf’ style=report_pdf;
ods pdf close;

c. ODS LAYOUT : Indiquer à SAS l’endroit où ODS REGION pourra être utilisé en précisant le début de la zone avec ODS LAYOUT START et la fin avec ODS LAYOUT END .

ods layout start;
ods layout end;

4. ODS REGION : préciser le point de départ du cadre avec X= et Y=. Puis donner la largeur (width) et la hauteur (height) du cadre.

ods region x=1cm y=1cm width=7cm height=2cm;
ods region x=13cm y=3cm width=7cm height=2cm;
ods region x=1cm y=5cm width=15cm height=1cm;
ods region x=4cm y=7cm width=15cm height=19cm;

Le code complète

ods listing close;
ods pdf file=‘C:/sasref/ods_layout.pdf’ style=report_pdf;
ods layout start;
*cadre 1 : adresse expéditeur;
ods region x=1cm y=1cm width=7cm height=2cm;
ods pdf text=‘Véronique Bourcier’;
ods pdf text=‘verronique.bourcier@sasreference.fr’;
ods pdf text=‘www.sasreference.fr’;
ods pdf text=‘Blog pour se former au logiciel SAS’;
*cadre 2 : adresse destinaire + date;
ods region x=13cm y=3cm width=7cm height=2cm;
ods pdf text=‘Lecteurs de SAS’;
ods pdf text=‘Rue des curieux’;
ods pdf text=‘00000 Francophones’;
ods pdf text=’ ‘;
ods pdf text=‘14 Juin 2009, Cologne’;
*cadre 3 : object;
ods region x=1cm y=5cm width=15cm height=1cm;
ods pdf text=‘Objet: Exemple avec ODS LAYOUT/REGION’;
*cadre 4 : contenu de la lettre;
ods region x=4cm y=7cm width=15cm height=19cm;
ods pdf text=‘Madame, Monsieur’;
ods pdf text=‘ ‘;
ods pdf text=“Le blog www.sasreference.fr est votre outil pour découvrir et redécouvrir la syntaxe de SAS. C’est aussi une communauté d’utilisateurs se retrouvant sur Facebook pour échanger sur de multiples thématiques :”;
ods pdf text=‘ ‘;
ods pdf text=‘+ Certification SAS’;
ods pdf text=‘+ Mémoire de stage’;
ods pdf text=‘+ Pharmaceutique’;
ods pdf text=‘+ Banque/assurance’;
ods pdf text=‘+ Milieu hospitalier’;
ods pdf text=‘+ Statistiques publiques’;
ods pdf text=‘+ Recherche’;
ods pdf text=‘+ Enseignement’;
ods pdf text=‘etc. ‘;
ods layout end;
ods pdf close;
ods listing;

3. Voir le résultat

Lectures complémentaires

• Des marges personnalisées pour vos rapports RTF
• Améliorer l’habillage de vos tableaux (débuter avec PROC TEMPLATE au moyen de PROC REPORT)

Des fichiers au format RTF (lisibles par word) ou PDF se créent sous SAS au moyen de la syntaxe inclues l’Output Delivery System (ODS). L’en-tête et le pied de page sont ajoutés au moyen des instructions TITLE et FOOTNOTE. Ici, vous verrez quel texte mettre dans l’instruction TITLE pour ajouter une image dans l’en-tête d’un fichier PDF.

1. Créer un fichier PDF

La table (dataset) CLASS de la bibliothèque SASHELP est affichée dans la sortie au moyen de l’instruction PROC PRINT.

Les instructions ODS LISTING CLOSE/ODS LISTING : Par défaut la table est envoyée dans la fenêtre OUTPUT de SAS, souvent appelée fenêtre LISTING. Cette destination ne nous intéresse pas. Elle est désactivée le temps du PROC PRINT au moyen de l’instruction ODS LISTING CLOSE et est réactivée à la fin avec ODS LISTING.

Les instructions ODS PDF/ODS PDF CLOSE : A la place, la première instruction ODS PDF définie le nom du fichier à créer. ODS PDF CLOSE ferme le fichier après y avoir écrit les informations du PROC PRINT.

ods listing close;
title ‘Mon logo’;
ods pdf file=‘C:/sasref/image_entete.pdf’;
proc print data=sashelp.class;
run;
ods pdf close;
ods listing;

L’instruction TITLE : L’instruction TITLE précède la première l’instruction ODS PDF. Si vous voulez la mettre après, je vous conseille de prendre l’habitude  d’indiquer à SAS de prendre le changement en compte en ajoutant une instruction ODS PDF juste après. Ainsi vous ferez appel à la même syntaxe avec ODS PDF et avec ODS RTF.

ods listing close;
ods pdf file=‘C:/sasref/image_entete.pdf’;
title ‘Mon logo’;
ods pdf;
proc print data=sashelp.class;
run;
ods pdf close;
ods listing;

2. Utiliser le style pour modifier la mise en page

L’image utilisée pour l’exemple est :

Pour changer la mise en page, il faut des styles. Les styles sont introduits par la lettre S. Afin que SAS fasse la différence entre un texte contenant la lettre S et un style, il faut faire précéder ce S d’un symbole.

Ici, l’accent circonflexe est choisi comme symbole précédent la lettre S pour définir un style. Pour le dire à SAS, il faut passer par l’instruction ODS ESCAPECHAR.

Les différents styles sont ensuite définis entre accolades.

title “^S={}”;

Deux styles parmi d’autres :

• PREIMAGE= donnera le chemin d’accès à l’image.
• JUST= indiquera l’alignement du titre (LEFT pour la gauche, CENTER pour le milieur et RIGHT pour la droite).

ods escapechar=’^';
ods listing close;
title “^S={just=left preimage=’C:/sasref/logo.jpg’}”;
ods pdf file=‘C:/sasref/image_entete.pdf’;
proc print data=sashelp.class;
run;
ods pdf close;
ods listing;

Important :  si vous rencontrez des difficultés avec une image au format .GIF, essayez avec une image au format JPG.

Cette syntaxe ne fonctionne pas avec ODS TAGSETS.EXCELXP.

3. Voir le résultat

Lectures complémentaires

• Numéroter ses pages avec ODS RTF
• Des marges personnalisées pour vos rapports
• Améliorer l’habillage de vos tableaux (débuter avec PROC TEMPLATE via PROC REPORT)
• Structurer les sauts de page

Mettre entre guillemets les mots contenus dans une macro variable SAS et les séparer par des virgules est possible au moyen des fonction %STR(), %QSYSFUNC et TRANWRD. Dans quel cas est-ce utile ? Comment se décompose cette syntaxe ?

1. Dans quel cas a-t-on besoin d’ajouter des guillemets et virgules ?

Lors de l’écriture d’une macro, vous pouvez avoir besoin d’autoriser plus d’un mot dans un des paramètres.

options mprint;

%macro test (multival=);

…

%mend test;

%test (multival=Alfred William);

Note : l’option MPRINT de l’instruction OPTIONS permettra de voir la résolution de la macro dans la log.

Ensuite, le contenu de ce paramètre traité comme une macro variable peut être appelé dans une condition. Dans l’exemple qui suit “Alfred”,”William” sera remplacée par la macro variable mise à jour.

proc print data=sashelp.class (where=(name = (“Alfred”,”William”));

run;

Il faut pour cela mettre la macro variable à jour en ajoutant des guillemets et la virgule comme séparateur.

2. Comment ajouter guillemets et virgules ?

2.1 Un mot

Dans le cas d’un paramètre avec un mot, on peut ajouter %str(%”) devant et derrière. Le symbole % permet d’introduire les caractères spéciaux comme le guillemet.

%let multival=%str(%”)&multival.%str(%”);

La macro donne alors :

%macro test (multival=);

%let multival=%str(%”)&multival.%str(%”);

proc print data=sashelp.class (where=(name = &multival.));

run;

%mend test;

%test (multival=Alfred);

2.2 Plus d’un mot

Pour mettre entre guillemets plus d’un mot, l’espace entre les mots sera remplacé par “,” (guillemet, virgule, guillemet) au moyen de la fonction TRANWRD.

%qsysfunc(tranwrd(&multival.,%str( ),%str(%”,%”)))

Pour exécuter cette fonction, qui n’a pas d’équivalent dans les macros fonctions, il faut englober le tout dans %SYSFUNC/%QSYSFUNC. La présence de la virgule oblige dans notre cas à utiliser %QSYSFUNC.

%macro test (multival=);

%let multival=%str(%”)%qsysfunc(tranwrd(&multival.,%str( ),%str(%”,%”)))%str(%”);

proc print data=sashelp.class (where=(name in (&multival.));

run;

%mend test;

%test (multival=Alfred William);

2.3 Plus d’un mot mis en majuscule

Enfin, pour ne pas tenir compte de la case, le texte peut être mis en majuscule au moyen de la fonction %UPCASE.

where=(upcase(name) in (%upcase(&multival.))

Cela donne :

%macro test (multival=);

%let multival=%str(%”)%qsysfunc(tranwrd(&multival.,%str( ),%str(%”,%”)))%str(%”);

proc print data=sashelp.class (where=(upcase(name) in (%upcase(&multival.))));

run;

%mend test;

%test (multival=Alfred William);

Lectures complémentaires

• Autres usages de la fonction %SYSFUNC
• Autres usages de la fonction TRANWRD

Sébastien Ringuedé a rédigé des questions du type Certification SAS Base. Ces questions sont en français. Comme pour la certification, il a mis en place un système proposant de manière “aléatoire” 70  de ces questions. Vous qvez deux heures pour y répondre.

Le lundi 25 mai 2009, quiz SAS en ligne
(débutez ce test de 2h entre 20h30 et 21h30 heure de Paris)

Deux exemplaires de son livre sur SAS sont à gagner :

SAS Introduction au décisionnel : méthode et maîtrise du langage

Pour plus d’informations, reportez-vous au site : http://www.sas-sr.com/viewtopic.php?id=175

Les options SAS modifiables au moyen de l’instruction globale OPTIONS peuvent être retrouvées dans une étape data ou autre au moyen de %SYSFUNC(GETOPTION()).

Par exemple, cette semaine, j’ai eu besoin de savoir combien de caractères par ligne je pouvais entrer dans ma sortie (fenêtre OUTPUT). En d’autres termes, je voulais connaître la LINESIZE et en fonction d’elle ajuster les colonnes de mon listing généré au moyen d’un simple PROC REPORT.

1. Lire dans la LOG l’information

L’instruction PROC OPTIONS permet de lister toutes les options dans la fenêtre LOG de SAS. En ajoutant OPTION=, l’affichage est réduit à la seule option LINESIZE.

proc options option=linesize;
run;

Dans notre exemple, l’option LINESIZE est de 91. Jusqu’à 91 caractères pourront être affichés sur une même ligne avec un PROC PRINT ou autre.

LINESIZE=91 Line size for SAS log and SAS procedure output
NOTE: PROCEDURE OPTIONS used (Total process time):
real time 0.00 seconds
cpu time 0.00 seconds

2. Sauvegarder l’information dans une macro variable

Pour illustrer la syntaxe %SYSFUNC(GETOPTION()), je choisi de sauvegarder l’information dans une macro variable appelée CURRENT_LS. Cette valeur est ensuite affichée dans la LOG au moyen de l’instruction %PUT.

%let current_ls=%sysfunc(getoption(linesize));
%put &current_ls.;

Vous pouvez directement inclure %SYSFUNC(GETOPTION()), dans une instruction globale comme TITLE si vous le souhaitez.

La liste des options du système SAS est grande. A vous d’explorer les possibilités que vous offre cette notation.

En SAS, l’instruction ALTER de PROC SQL a la capacité de changer le libellé d’un data set, modifier le format/informat ou le libellé d’une variable. Mais son principale intérêt réside dans sa capacité à modifier la longueur d’une variable caractère sans changer la position de la variable dans le data set.

1. Comparaison avec deux autres méthodes : PROC DATASETS et l’étape DATA

Alors que PROC DATASETS permet de modifier le format/informat, le libellé d’une variable ou de renommer une variable, il ne permet pas de changer la longueur d’une variable.

Avec une simple étape data, il est possible de modifier la longueur de la variable en ajoutant une instruction LENGTH avant de lire les donnees avec un SET/MERGE… Mais la séquence d’affichage des variables n’est plus respecté. Il faut soit avoir sauvegardé au préalable l’ordre d’affichage (ou l’entrer manuellement, bof !), soit utiliser l’instruction ALTER de PROC SQL…

2. Quelques données pour tester soi-même

* Create two formats SEX and GENDER;
proc format;
value $ sex ‘M’=‘Male’
‘F’=‘Female’;
value $ gender ‘M’=‘Homme’
‘F’=‘Femme’;
run;

*Create a data set named CLASS ;
*based on the SASHELP.CLASS data set ;
*adding the SEX format to the SEX variable;
data class;
set sashelp.class;
format sex sex.;
run;

3. L’instruction ALTER pour modifier la longueur d’une variable

Dans l’instruction ALTER de PROC SQL, le mot-clé MODIFY introduit deux variables SEX et NAME à modifier.

proc sql;
alter table class (label=‘Changes with PROC SQL and ALTER’)
modify sex format=$gender.,
name char(20) label=‘Student Name’;
quit;

Changement le plus intéressant :

• La longueur de la variable caractère NAME est à l’origine 8. Elle est remplacée par 20.

Quelques changements secondaires :

• Libellé de data set : Dans l’exemple ci-dessus le data set CLASS a pour libellé ‘Changes with PROC SQL and ALTER’.
• format de variable : Le format de la variable SEX est à l’origine $SEX. Il est ici remplacé par le format $GENDER.
• Libellé de variabel : Le libellé de la variable NAME est ajouté. Il s’agit de ‘Student Name’.

A retenir :

1. Seules les variables caractères peuvent avoir leur longueur changées au moyen de l’instruction ALTER.
2. Cette instruction permet certe de modifier le format d’un data set. Néanmoins, elle ne permet pas de supprimer tous les formats d’un data set.

Lectures complementaires :

• Modifier un data set sans le lire (formater, renommer, libeller)
• Changer la sequence d’affichage des variables
• 4 etapes de base pour creer un data set avec PROC SQL

SAS Online DOC

• The SQL Procedure

Selon le pays les nombres sont présentés de manière différente. COMMA et COMMAX sont deux formats utilisés par SAS pour représentés les nombres mais ne s’applique pas au cas français. Vous verrez donc comment créer le format qui vous convient avec l’instruction PICTURE de PROC FORMAT.

1. La différence français/anglais

Les francophones présentent les nombres différemment des anglophones sur deux points.

• Les milliers : Les chiffres des milliers sont séparés par un espace alors que les américains utilisent la virgule
• Les décimales : Les décimales sont séparées par une virgule en français contre un point en anglais

2. La représentation par défaut de SAS

Par défaut, les nombres sous SAS sont simplifiés comme sur une calculatrice.

• Les milliers : le seul séparateur est celui des décimales
• Les décimales : le point fait office de séparateur pour les décimales

Pour une présentation à l’anglais, il faudra appliquer le format COMMA. Il n’existe à ma connaissance qu’une semi version française : le format COMMAX. En effet celui-ci utilise bien la virgule pour séparer les entiers des décimales mais il utilise aussi le point et non le blanc pour séparer les milliers. On préférera donc créer un format avec l’instruction PICTURE.

2. Un exemple

Créer un format : dans le cas présent, les nombres seont affichés jusqu’à 999999,99,  en ajoutant un espace entre les milliers et un virgule pour les décimales.

• L’usage du 0 : il n’y aura pas de zéro affiché à l’avant du nombre si celui-ci est plus petit que 100000.
• L’usage du 9 : Les décimales s’afficheront toujours avec deux chiffres après la virgules même si le second chiffre est un zéro.

proc format;
picture commafr other=’000 000,99′;
run;

Appliquer les formats COMMA,  COMMAX et format personnel

Dans cette étape data trois variables sont créées chacune avec une observation.

Dans les trois cas, un format avec une extension 9.2 est ajouté de manière permanente. On indique à SAS que le nombre ne dépassera normalement pas 9 caractères dont 2 pour les décimales.

data fr_en;
format eg_english comma9.2
eg_semifrench commax9.2
eg_french commafr9.2;
eg_english=100987.24;
eg_semi_french=100987.24;
eg_french=100987.24;
run;

Voir le résultat

eg_english   eg_semifrench   eg_french

100,987.24     100.987,24    100 987,24

La variable EG_ENGLISH (exemple, anglais) reçoit, quant à elle, un format COMMA9.2 pour un affichage à l’américaine/l’anglais.

La variable EG_SEMIFRENCH (exemple,respectant partiellement la syntaxe française) reçoit u nformat COMMAX9.2.

La variable EG_FRENCH (exemple, français) reçoit le format créé manuellement COMMAFR9.2 pour un affichage avec un blanc entre chaque groupe de trois chiffres parmi dans la partie entière et deux chiffres pour la partie décimale.

Lectures complémentaires

• Parler français : les heures sous la forme 9h30
• Arrondir ses chiffres avant d’appliquer un format
• Ajouter une date dans un nom de fichier Word, Excel,…
• Afficher 7h30 du matin sous la forme 07:30

SAS Online Doc

• COMMAw.d Format
• COMMAXw.d Format
• PICTURE Statement

Aujourd’hui étant mon anniversaire, je fais la paresseuse et vous communique un petit fichier SAS, reçu ce jour (merci Alex), à faire tourner sous Windows, écouteurs en place, pour la prochaine fois qu’un collègue ou pote qui connaît SAS soufflera ses bougies. Amusez-vous bien !

%let pc=1;

%macro sasreference_fr(note,octave,length);

select(&note.);
when (‘A’) call sound (55*(2**&octave.),&length.*160*&pc.);
when (‘A#’) call sound (58*(2**&octave.),&length.*160*&pc.);
when (‘Bb’) call sound (58*(2**&octave.),&length.*160*&pc.);
when (‘B’) call sound (62*(2**&octave.),&length.*160*&pc.);
when (‘C’) call sound (65*(2**&octave.),&length.*160*&pc.);
when (‘C#’) call sound (69*(2**&octave.),&length.*160*&pc.);
when (‘Db’) call sound (69*(2**&octave.),&length.*160*&pc.);
when (‘D’) call sound (73.5*(2**&octave.),&length.*160*&pc.);
when (‘D#’) call sound (73.5*(2**&octave.),&length.*160*&pc.);
when (‘Eb’) call sound (78*(2**&octave.),&length.*160*&pc.);
when (‘E’) call sound (82*(2**&octave.),&length.*160*&pc.);
when (‘F’) call sound (87*(2**&octave.),&length.*160*&pc.);
when (‘F#’) call sound (92.5*(2**&octave.),&length.*160*&pc.);
when (‘Gb’) call sound (92.5*(2**&octave.),&length.*160*&pc.);
when (‘G’) call sound (98*(2**&octave.),&length.*160*&pc.);
when (‘G#’) call sound (104*(2**&octave.),&length.*160*&pc.);
when (‘Ab’) call sound (104*(2**&octave.),&length.*160*&pc.);
when (‘R’) call sleep((&length./3)*&pc.,1);
otherwise;
end;
%mend sasreference_fr;

data _null_;
%sasreference_fr(‘C’,3,1);
%sasreference_fr(‘C’,3,1);
%sasreference_fr(‘D’,3,2);
%sasreference_fr(‘C’,3,2);
%sasreference_fr(‘F’,3,2);
%sasreference_fr(‘E’,3,4);

%sasreference_fr(‘R’,3,2);

%sasreference_fr(‘C’,3,1);
%sasreference_fr(‘C’,3,1);
%sasreference_fr(‘D’,3,2);
%sasreference_fr(‘C’,3,2);
%sasreference_fr(‘G’,3,2);
%sasreference_fr(‘F’,3,4);

%sasreference_fr(‘R’,3,2);

%sasreference_fr(‘C’,3,1);
%sasreference_fr(‘C’,3,1);
%sasreference_fr(‘C’,4,2);
%sasreference_fr(‘A’,4,2);
%sasreference_fr(‘F’,3,1);
%sasreference_fr(‘F’,3,1);
%sasreference_fr(‘E’,3,2);
%sasreference_fr(‘D’,3,4);

%sasreference_fr(‘R’,3,2);

%sasreference_fr(‘Bb’,4,1);
%sasreference_fr(‘Bb’,4,1);
%sasreference_fr(‘A’,4,2);
%sasreference_fr(‘F’,3,2);
%sasreference_fr(‘G’,3,2);
%sasreference_fr(‘F’,3,4);
run;

Pour les curieux, je vous invite à consulter les programmes des chansons suivantes sur www.developpez.com :

• Deep Purple, Smoke on the Water
• Ils ont des chapeaux ronds
• Old Mac Donald had a Farm
• Stratovarius
• Red Hot Chili Pepper, Around the World (intro)
• Mac Gyver, générique
• Mario Theme
• Le petit bonhomme en mousse

Les plus téméraires s’intéresserons à la publication “Making Music in SAS“. Vos créations pourront être publiées sur le blog.

A lire aussi www.sasreference.fr :

• Penser conditionnel (3/3) : Case When

Les métadonnées (metadata) peuvent se présenter sous la forme de tables SAS (data sets). Elles donnent une description d’une table SAS.

Si un data set existe déjà, vous pouvez retrouver des métadonnées dans le dictionnaire COLUMNS ou avec un PROC CONTENTS : nom de variable, position, type, longueur, format, etc.

Mais ce qui est intéressant est de préparer ce descriptif à l’avance pour créer ou actualiser un jeu de données.

Ici, nous verrons comment définir des métadonnées et les appliquer sur un data set existant.

1. Créer un data set de base pour l’exemple

Le data set AE contient la variable SASREF qui prend la valeur 1.

data ae;
   sasref=1;
run;

proc contents data=ae varnum;
run;

2. Créer les métadonnées pour l’exemple

Le data set contenant les métadonnées est composé de six variables :

• La position des variables (MYVARNUM)
• Le nom des variables (MYNAME)
• Leur libellé (MYLABEL)
• Leur type (numérique ou alphanumérique) (MYTYPE)
• La longueur des variables (MYLENGTH)
• Leur format (MYFORMAT)

data meta_ae;
   length myvarnum 8 myname $8 mylabel $14 mytype $1 mylength 8 myformat $11;
   input myvarnum myname mylabel 12-25 mytype mylength myformat;
   datalines;
1 SUJECTID Subject Number C 10 10.
2 RECID    Record ID      N 8 10.
3 AETERM   Term           C 60 60.
4 AE_SD    Starting Day   N 8 2.
5 AE_SM    Starting Month N 8 2.
6 AE_SY    Starting Year  N 8 4.
7 AE_SDAT  Starting Date  N 8 DATE9.
8 AESEV    Severity       N 8 AESEV.
;
run;

3. Créer le format AESEV pour l’exemple

Dans les métadonnées, le format AESEV s’applique à la variable sur la gravité (severity) de l’effet secondaire (adverse event).

proc format;
   value aesev 1=‘Severe’
               2=‘Mild’;
run;

4. Objectif

Le but est de construire une étape data où les instructions ATTRIB sont listées avant de lire les données de AE. Ces ATTRIB servent à définir les variables du data set AE dans l’ordre indiqué par MYVARNUM dans les métadonnées avec leur libellé, type, longueur et format.

De plus, seules les variables listées dans les métadonnées seront gardées. La variable SASREF devra disparaître.

5. Lister les variables à garder dans une macro variable

Afin de ne garder que les variables présentent dans les métadonnées, une liste en est faite. Elle est sauvegardée dans la macro variable MYNAME_LST. Cette liste sera ensuite appelée dans une option KEEP=.

proc sql noprint;
   select distinct myname into : myname_lst separated by ‘ ‘
   from meta_ae;
quit;

6. Générer le programme

Le programme est généré au moyen d’un DATA _NULL_.

Un tri préalable des métadonnées : L’ordre dans lequel les instructions ATTRIB seront listées affectera l’ordre d’apparition des variables. L’instruction PROC SORT s’assure que ces instructions apparaîtront dans l’ordre donnée dans les métadonnées par la variable MYVARNUM.

proc sort data=meta_ae;
   by myvarnum;
run;

Un catalogue pour écrire le programme : J’ai choisi ici de sauvegarder le programme généré dans un catalogue pointé dans l’étape data sous le nom SASREF. Ce nom est précédemment défini au moyen de l’instruction FILENAME.

Après exécution du programme (%INCLUDE),

• le FILENAME désignant ce catalogue est désactivé (instruction FILENAME) et
• le catalogue lui-même est supprimé (PROC DATASETS).

Vous pouvez choisir d’utiliser un simple nom de fichier à supprimer ensuite manuellement ou avec une commande Unix/Windows (cf instruction FILENAME en vert).

filename sasref catalog ‘work.sasref.meta.source’;
*filename sasref ‘C:/sasref/attrib_meta.sas’;

L’activation de l’instruction *FILE PRINT; à la place de FILE SASREF vous permettra de voir votre code dans la fenêtre OUTPUT lors du développement du code.

Des outils optionnels : Les arobases @ et +(-1) sont simplement là pour l’apparence du programme mais n’affecte en aucun cas l’exécution du code. Ils sont donc optionnels.

• Les arobases font débuter le texte à la position donnée par le nombre qui suit.
• Les +(-1) permettent de revenir d’une position en arrière avant de continuer à taper le texte. Ainsi le blanc créé automatiquement avec PUT  n’existe plus.

Distinguer les variables numériques des variables alphanumériques : Un symbole dollar $ est obligatoire pour définir la longueur et le format des variables. Il est donc de faire varier le texte en fonction du type (variable MYTYPE=N ou C).

data _null_;
   set meta_ae end=eof;
   *file print;
   file sasref;
   if _N_=1 then put ‘data ae (keep= &myname_lst.);’;
   put @4 ‘attrib ‘ myname @23 “label = ‘” mylabel +(-1) “‘” ;
   if mytype=‘N’ then
      do;
         put @23 ‘length = ‘ mylength;
         put @23 ‘format = ‘ myformat +(-1)’;';
      end;
   else if mytype=‘C’ then
      do;
         put @23 ‘length = $’ mylength;
         put @23 ‘format = $’ myformat +(-1) ‘;’;
      end;
   if eof then
      do;
         put @3 ’set ae;’;
         put ‘run;’;
      end;
run;

%include sasref;
filename sasref;

proc datasets memtype=catalog ;
   delete sasref;
run;

7. Le résultat

Au final, le data set AE contient les variables listées dans les métadonnées et seulement ces variable

proc contents data=ae varnum;
run;

Lectures complémentaires :

• Les deux dictionnaires SAS les plus utilisés : TABLES et COLUMNS
• Créer un fichier .sas automatiquement
• Changer la séquence d’affichage des variables
• Ecrire un texte avec l’instruction PUT

Je vous propose une série d’articles sur la thématique “Parler français avec SAS”. Je reprend les notions du précédent article sur les heures pour nous intéresser à la manière d’ajouter la lettre h séparant habituellement les heures des minutes ? Voici un exemple structuré en 4 parties.

1. L’instruction PICTURE de PROC FORMAT

Ici est créé un format HR_FR au moyant de l’instruction PICTURE dans une procédure PROC FORMAT. Il s’applique à des données exprimant les heures SAS.

proc format;
picture hr_fr other=‘%Hh%0M’ (datatype=time);
run;

2. Créer un data set pour illustrer le sujet

L’étape data crée un data set HEURE_FR contenant une variable DEBUT avec deux observations. Ces records sont des heures exprimées en SAS Time.

data heure_fr;
debut=‘9:05′t;
output;
debut=‘14:05′t;
output;
run;

3. Appliquer le format HR_FR à la variable DEBUT

Le temps de la procédure PROC PRINT est ajouté le format HR_FR à la variable DEBUT .

proc print data=heure_fr;
format debut hr_fr.;
run;

4. Voir Le résultat de la procédure PROC PRINT

debut
9h05
14h05

Lectures complémentaires :

• Ajouter une date dans un nom de fichier Excel, Word, etc.
• Afficher 7h30 sous la forme 07:30

Sous SAS, en créant un fichier .xls ou .rtf avec la syntaxe de l’ODS (Output Delivery System), il est parfois pratique d’ajouter dans le nom du fichier une date. Par exemple : listing_20090311.xls.

Nous verrons ici plusieurs représentations de la date et de l’heure : afin d’avoir des noms triables par ordre chronologique, l’année apparaît avant le mois et le jour.

La syntaxe proposée, %SYSFUNC(fonction, format), s’utilise dans d’autres cas que la définition d’un nom de fichier (.rtf, .xls, …). De manière générale, elle sert à utiliser des fonctions en dehors d’une étape data ou d’une procédure. Par exemple, elle peut être ajoutée dans une instruction TITLE.

1. L’objectif pour un programme exécuté le 11 mars 2009

L’objectif de l’exemple qui suit est d’obtenir un fichier .xls nommé class_20090311.xls dont la date change selon le jour de sa création.

La version fixe se présente ainsi : un fichier .xls est créé au moyen de ODS TAGSETS.EXCELXP. Il contient les données du data set SASHELP.CLASS. La création d’un fichier dans la fenêtre OUTPUT est suspendu le temps de la création du fichier .xls au moyen de l’instruction ODS LISTING CLOSE et ODS LISTING.

ods listing close;
ods tagsets.excelxp file='C:/sasref/class_20090311.xls';
proc print data=sashelp.class;
run;
ods tagsets.excelxp close;
ods listing;

2. Ajouter de la flexibilité avec %SYSFUNC

A présent, la date est définie automatiquement au moyen de la macro fonction %SYSFUNC. Cette fonction est dans ce cas particulier composée de deux paramètres :

• la date SAS extraite au moins de la fonction TODAY()
• le format à appliquer sur cette date

Résoudre le contenu de la fonction %SYSFUNC grâce aux guillemets doubles : la fonction %SYSFUNC fait partie du langage macro. Dès lors, pour obtenir la résolution de son contenu, il faut utiliser des guillemets doubles.

Retrouver la date d’exécution du programme grâce aux fonctions TODAY() ou DATE () : La fonction TODAY() retourne la date SAS d’exécution du programme. Une alternative est la fonction DATE(). Dans les deux cas, la fonction ne contient pas de paramètre.

Le format YYMMDDn. pour écrire 20090311 : Le format YYMMDDn. est un sous-ensemble de la fonction YYMMDD composée de 8 caractères, sauf indication contraire, faisant apparaître :

• l’année en premier,
• suivi du mois en chiffre et
• enfin du jour.

Ce format avec l’extension “n” a la particularité de ne pas utiliser de symbole ou espace séparatant le jour, du mois et de l’année. Les 8 caractères par défaut de la fonction laisse de la place à une année exprimée par 4 chiffres.

ods listing close;
ods tagsets.excelxp file="C:/sasref/class_%sysfunc(today(),yymmddn.).xls";
proc print data=sashelp.class;
run;
ods tagsets.excelxp close;
ods listing;

3. Tester d’autres formes d’affichage

3.1 Ajouter des tirets bas entre le jour, le mois et l’année grâce à la fonction TRANSLATE

class_2009_03_11.xls : pour avoir des tirets bas (underscore) entre le jour, le mois et l’année, il n’existe pas de format directement applicable. Une solution est alors d’utilise un autre symbole et de le remplacer avec la fonction TRANSLATE.

Ici le format YYMMDD10 retourne une date de la forme 20009-03-11. Les traits d’union (hyphen) sont remplacés par des tirets bas (underscore).

ods tagsets.excelxp file=“C:/sasref/class_%sysfunc(translate(%sysfunc(today(),yymmdd10.),’_',’-')).xls”;

3.2 Ajouter une heure avec TIME() et PICTURE (class_20090311_113057.xls)

Quelle fonction pour l’heure ? : La fonction TIME() retourne l’heure sous la forme d’un time SAS.

Quels formats pour l’heure ? : Le format HHMM. retournera les heures et les minutes, tandis que le format TIME. retournera en plus les secondes. Dans les deux cas cependant, les heures avant 10h apparaissent avec seulement un chiffre : 9:30 et non 09:30. Un espace remplace le zéro manquant.

L’instruction PICTURE de PROC FORMAT pour un format personalisé : Une solution est de créer un format personalisé au moyen de l’instruction PICTURE (PICTURE statement). Comme les lettres H, M et S n’inclus pas de zéro devant (leading zero) pour les nombres à un chiffres, il faut les ajouter dans l’instruction PICTURE.

Note : %0S fait référence aux secondes. Il n’est obligatoire que si vous voulez des secondes dans votre texte final.

proc format;
   picture sasref other=‘%0H%0M%0S’ (datatype=time);
run;

Ensuite, 

• pour une heure à quatre chiffres (heure + minutes) , il faudra préciser le nombre 4 dans l’appel du format.
• pour une heures à six chiffres (heures + minutes + secondes), c’est 6 qui doit être ajouté

ods tagsets.excelxp file=“C:/sasref/class_%sysfunc(today(),yymmddn.)_%sysfunc(time(),sasref6.).xls”;

Lectures complémentaires sur www.sasreference.fr

ODS

• Mes premiers pas avec ODS TAGSETS.EXCELXP (Partie 1/3)
• Mes premiers pas avec ODS TAGSETS.EXCELXP (Partie 2/3)
• Mes premiers pas avec ODS TAGSETS.EXCELXP (Parite 3/3)

Les fonctions

• Enlever certains caractères spéciaux avec la fonction TRANSLATE

Les formats :

• Afficher 7h30 sous la forme 07:30

Les macros fonctions

• Additionner deux macros variables : la fonction %EVAL (usage de %SYSFUNC)
  
• Combien d’observations dans mon data set (usage de %SYSFUNC)

SAS Online Doc

%SYSFUNC

• %SYSFUNC and %QSYSFUNC Functions
• %SYSFUNC : Summary Descriptions and Syntax

Formats sorted by Categories (inclus : Date and Time)

• YYMMDDw.
• YYMMDDwx.
• HHMMw.d
• TIMEw.d

Format et PICTURE

• Picture Statement

Aujourd’hui je vous propose quelques options pour travailler l’affichage de longs titres et pieds-de-pages qui sont insérés dans une feuille de calcul. Cela complètera les articles Ajouter les titres et pieds-de-page dans une feuille de calcul (EMBEDDED_TITLES=, EMBEDDED_FOOTNOTES= et l’option ajoutée lors de la mise à jour de l’article SKIP_SPACE=) et Personnaliser l’apparence des titres et des pieds-de-page dans un fichier .xls (ODS TAGSETS.EXCELXP et PROC TEMPLATE).

Je vais continuer à utiliser le style XLS_TITL pour les couleurs, polices, etc. proposé dans le précédent article pour mes captures d’écran.

1. Par défaut, un titre partiellement visible

Lorsqu’un titre est plus long que la largeur fournie par les colonnes du tableau affiché, seule une partie du titre est visible.

2. Une solution valable seulement sur les anciennes versions de TAGSETS.EXCELXP

Une solution est d’utiliser la place disponible par les autres cellules. L’instruction global OPTIONS NOCENTER suffira. Mais cette fonctionnalité ne fonctionne pas avec les dernières mises à jour de TAGSETS.EXCELXP.

3. Agrandir la hauteur de la ligne

Pour agrandir la hauteur de la ligne, il vous faudra utiliser l’option ROWS_HEIGHTS= composée de 7 nombres. Les quatrième et cinquième nombres font respectivement référence à la hauteur des lignes pour les titres et la hauteur des lignes pour les pieds-de-page.

Par défaut, on a: ROWS_HEIGHTS=’0,0,0,0,0,0,0′.

En appliquant cette option à notre exemple, cela donne : ROW_HEIGHTS=’0,0,0,45,40,0,0′.

4. Le code pour l’exemple

ods listing close;
ods tagsets.excelxp file=‘C:/sasref/class.xls’ /*style=xls_titl*/
options(embedded_titles=‘yes’
embedded_footnotes=‘yes’
row_heights=’0,0,0,45,40,0,0′);

title ‘Titre sur 2 lignes’;
footnote ‘Pied-de-page sur 2 lignes’;
ods tagsets.excelxp;

proc report data=sashelp.class nowd;
columns name age;
define name/display ‘Nom’;
define age /display ‘Age’;
run;

ods tagsets.excelxp close;
ods listing;

Lectures complémentaires

• Personnaliser l’apparence des titres et pieds-de-page dans un fichier .xls (ODS TAGSETS.EXCELXP et PROC TEMPLATE)
• Choisir ses couleurs sous SAS
• Ajouter les titres et pieds-de-page dans un fichier .xls
• 9 points pour personnaliser ses titres
• En-tête et pied-de-page avec TAGSETX.EXCELXP (print_header et print_footer)
• Mes premiers pas avec ODS TAGSETX.EXCELXP (1/3)
• Mes premiers pas avec ODS TAGSETX.EXCELXP (2/3)
• Mes premiers pas avec ODS TAGSETS.EXCELXP (3/3)
• Mettre à jour ses TAGSETS pour EXCELXP

Après vous avoir présenté les options EMBEDDED_TITLES et EMBEDDED_FOOTNOTES dans l’article : Ajouter les titres et pieds-de-page dans une feuille de calcul du fichier .xls, je vous propose de personnaliser l’apparence de vos titres au moyen d’un nouveau style créé dans une instruction PROC TEMPLATE.

1. Créer un style personnaliser pour ses titres et pieds de page

Le nouveau style s’appelle XLS_TITL. Comme base, nous prenons un style existant sous SAS : STYLES.DEFAULT et faisont quelques modification au niveau des titres et pieds-de-page.

proc template;
define style styles.xls_titl;
parent=styles.rtf;

style systemtitle from systemtitle /
background=transparent
foreground=#000000
font_style=roman
font_weight = medium
font_size=18pt
font_face=‘Arial’;

style systemfooter from systemfooter/
background=transparent
foreground=#000000
font_style=roman
font_weight = medium
font_size=14pt
font_face=‘Arial’;

end;
run;

• BACKGROUND modifie la couleur de font des cellules (voir l’article : choisir ses couleurs sous SAS). Notez que le mot TRANSPARENT ne fonctionne pas avec la version 1.86 de TAGSETS.EXCELXP mais avec certaines versions plus anciennes.
• FOREGROUND modifie la couleur du texte
• FONT_STYLE empêche l’inclinaison par défaut (enlever l’italique : roman, mettre en italic : italic)
• FONT_WEIGHT enlève la côté gras présent par défaut (enlever les gras : medium, mettre en gras : bold)
• FONT_SIZE défini la taille des caractères
• FONT_FACE liste les polices à utiliser. Si plusieurs polices sont listées entre guillemets, la première disponible sur l’ordinateur sera retenue.

2. Appeler le style dans l’instruction ODS TAGSETS.EXCELXP

L’option STYLE= a été ajouté dans la première instruction ODS TAGSETS.EXCELXP . Elle est suivie du nom du style créé préalablement. Cela donne STYLE=XLS_TITL.

ods listing close;
ods tagsets.excelxp file=‘C:/sasref/class.xls’ style=xls_titl
options(embedded_titles=‘yes’
embedded_footnotes=‘yes’);

title ‘Titre’;
footnote ‘Pied’;
ods tagsets.excelxp;

proc report data=sashelp.class nowd;
columns name age;
define name/display ‘Nom’;
define age /display ‘Age’;
run;

ods tagsets.excelxp close;
ods listing;

Pour le reste des explications concernant cette syntaxe, reportez-vous à l’article de la semaine dernière.

3. Voir le résultat

Lectures complémentaires :

• Choisir ses couleurs sous SAS
• Ajouter les titres et pieds-de-page dans un fichier .xls
• 9 points pour personnaliser ses titres
• En-tête et pied-de-page avec TAGSETX.EXCELXP (print_header et print_footer)
• Mes premiers pas avec ODS TAGSETX.EXCELXP (1/3)
• Mes premiers pas avec ODS TAGSETX.EXCELXP (2/3)
• Mes premiers pas avec ODS TAGSETS.EXCELXP (3/3)
• Mettre à jour ses TAGSETS pour EXCELXP

Lors de la création d’un fichier .xls au moyen de la syntaxe ODS TAGSETS.EXCELXP sous SAS, le contenu des instructions TITLE et FOOTNOTE est envoyé respectivement dans l’entête et pied-de-page du fichier. Ils ne sont donc visibles qu’à l’impression.

Pour insérer le contenu des instructions TITLE et FOOTNOTE dans la feuille de calcul, il faudra ajouter deux options dans l’instruction ODS TAGSETX.EXCELXP : EMBEDDED_TITLES etEMBEDDED_FOOTNOTES.

1. Le code

Voici le code pour l’exemple. Vous noterez que j’ai rajouté une instruction ODS… juste après les instructions TITLE et FOOTNOTE. Cela permet à SAS de mettre à jour les titres et pieds-de-page qu’il a en mémoire. Cela sera pratique lorsque vous aurez plusieurs feuilles de calculs avec des titres différents. Autrement, vous pouvez ajouter les instructions TITLE et FOOTNOTES avant la première instruction ODS TAGSETS.EXCELXP.

ods listing close;
ods tagsets.excelxp file=‘C:/sasref/class.xls’
options(embedded_titles=‘yes’
embedded_footnotes=‘yes’);

title ‘Titre’;
footnote ‘Pied’;
ods tagsets.excelxp;

proc report data=sashelp.class nowd;
columns name age;
define name/display ‘Nom’;
define age /display ‘Age’;
run;

ods tagsets.excelxp close;
ods listing;

L’option NOWD est propre à un environnement Windows. Cela évite l’ouverture de la fenêtre REPORT

2. Voir le résultat

3. Enlever les lignes blanches entre les titres/pieds-de-page et la table

Pour empêcher l’insertion d’une ligne entre le(s) titre(s) et la table, le(s) pied(s)-de-page et la table, il faut faire appel à l’option SKIP_SPACE=.

Avant d’aller plus loin, il faut noter que

• la ligne d’espace entre le titre est la table est lié au TITRE et
• la ligne entre la table et le pied-de-page est lié à la TABLE et non au pied-de-page.

Cette option de l’instruction ODS TAGSETS.EXCELXP est composée de 5 nombres.

• Le premier nombre fait référence à la TABLE
• Le 3ème nombre est lié au TITRE
• Le 4ème nombre fait référence au PIED-DE-PAGE.

Par défaut SKIP_SPACE=’1,0,1,1,1′.

Pour ôter les lignes séparant la table des titres et pieds-de-page, on aura : SKIP_SPACE=’0,0,0,1,1′. On enlevera la ligne après la table avec le premier zéro et la ligne après le titre avec le troisième zéro.

A venir

Je vous propose de découvrir dans les deux articles à venir des compléments sur les titres et pieds-de-page avec ODS TAGSETS.EXCELXP :

• Créer un style pour personnaliser les couleurs, polices des titres/pieds-de-page avec un PROC TEMPLATE.
• Utiliser un titre plus grand que la largeur donnée par les colonnes du tableau

Lectures complémentaires

• 9 points pour personnaliser ses titres
• En-tête et pied-de-page avec TAGSETX.EXCELXP (print_header et print_footer)
• Mes premiers pas avec ODS TAGSETX.EXCELXP (1/3)
• Mes premiers pas avec ODS TAGSETX.EXCELXP (2/3)
• Mes premiers pas avec ODS TAGSETS.EXCELXP (3/3)
• Mettre à jour ses TAGSETS pour EXCELXP